У меня следующая задача: нужно считать внешней обработкой две таблицы из Экселя желательно в какие-нибудь временные таблицы, обработать их запросом и вывести результат запроса в табличную часть обработки. Подскажите плиз куда лучше считать файлы, чтобы потом и удобно к ним было обращаться запросом? Ничего хорошего в "Простые примеры разработки не нашёл". Надеюсь на вашу помощь.

========================

прочитай в таблицы значений, не забыв указать тип для колонок

а дальше
Код 1c:
Запрос.УстановитьПараметр("ТЗ",    ТЗ);
ВЫБРАТЬ ТЗ.Поле1
ИЗ &ТЗ КАК ТЗ

====================

Что-то я не в курю с кодом из помощи:

Код 1c:
        КЧ = Новый КвалификаторыЧисла(12,2);
        КС = Новый КвалификаторыСтроки(20);
        Массив = Новый Массив;
        Массив.Добавить(Тип("Строка"));
        ОписаниеТиповС = Новый ОписаниеТипов(Массив, , КС);
        Массив.Очистить();
        Массив.Добавить(Тип("Число"));
        ОписаниеТиповЧ = Новый ОписаниеТипов(Массив, , ,КЧ);
 
        // Создание таблицы значений  
        ТаблицаЗначений = Новый ТаблицаЗначений;
        // добавим в таблицу значений три колонки 
        ТаблицаЗначений.Колонки.Добавить("Отдел",ОписаниеТиповС,"Отдел");
        ТаблицаЗначений.Колонки.Добавить("Сотрудник",ОписаниеТиповС,"Фамилия сотрудника");
        ТаблицаЗначений.Колонки.Добавить("Оклад",ОписаниеТиповЧ,"Оклад");
        // добавим строку 
        Стр=ТаблицаЗначений.Добавить();
        Стр.Отдел="Отдел 1";
        Стр.Сотрудник="Иванов";
        Стр.Оклад=5600;

Нафига такой гемор с типами до комментариев "// Создание таблицы значений "?

================

Код 1c:
Менеджер = Новый МенеджерВременныхТаблиц; 
    Запрос.МенеджерВременныхТаблиц = Менеджер; 
    Запрос.Текст = 
    "ВЫБРАТЬ
    |    ДанныеОЛимитах.БанковскийСчет КАК БанковскийСчет,
    |    ДанныеОЛимитах.ЛимитКредита КАК Лимит,
    |    ДанныеОЛимитах.НеуменьшаемыйОстаток КАК НеуменьшаемыйОстаток
    |    ПОМЕСТИТЬ Лимиты
    |    ИЗ &ТЧДанныеОЛимитах КАК ДанныеОЛимитах";
    Запрос.УстановитьПараметр("ТЧДанныеОЛимитах", ДанныеОЛимитах);
    Запрос.Выполнить();
 
    Запрос.Текст = 
    "ВЫБРАТЬ
    |    ДанныеОКредитах.БанковскийСчет КАК БанковскийСчет,
    |    ДанныеОКредитах.КонтрагентБанк КАК КонтрагентБанк,
    |    ДанныеОКредитах.ДоговорСКонтрагентомБанком КАК ДоговорСКонтрагентомБанком
    |    ПОМЕСТИТЬ Кредиты
    |    ИЗ &ТЧДанныеОКредитах КАК ДанныеОКредитах";
    Запрос.УстановитьПараметр("ТЧДанныеОКредитах", ДанныеОКредитах);
    Запрос.Выполнить();
 
 
    Запрос.Текст = 
    "ВЫБРАТЬ
    |    ДвиженияДСОстаткиИОбороты.Валюта КАК Валюта,
    |    ДвиженияДСОстаткиИОбороты.БанковскийСчет.Банк КАК БанковскийСчетБанк,
    |    ДвиженияДСОстаткиИОбороты.СуммаНачальныйОстаток КАК СуммаНачальныйОстаток,
    |    ДвиженияДСОстаткиИОбороты.СуммаПриход КАК СуммаПриход,
    |    ДвиженияДСОстаткиИОбороты.СуммаРасход КАК СуммаРасход,
    |    ДвиженияДСОстаткиИОбороты.СуммаКонечныйОстаток КАК СуммаКонечныйОстаток,
    |    ДвиженияДСОстаткиИОбороты.БанковскийСчет КАК БанковскийСчет,
    |    0 КАК Лимит,
    |    0 КАК НеуменьшаемыйОстаток,
    |    0 КАК КредитПолученный
    |ИЗ
    |    РегистрНакопления.ДвиженияДС.ОстаткиИОбороты(
    |        &НачалоПериода,
    |        &КонецПериода,
    |        Период,
    |        ДвиженияИГраницыПериода,
    |        Организация = &Организация
    |            И Вариант = &Вариант) КАК ДвиженияДСОстаткиИОбороты";
 
    Запрос.Текст = Запрос.Текст+"
    |
    |ОБЪЕДИНИТЬ ВСЕ
    |
    |ВЫБРАТЬ
    |    Лимиты.БанковскийСчет.ВалютаДенежныхСредств,
    |    Лимиты.БанковскийСчет.Банк,
    |    0,
    |    0,
    |    0,
    |    0,
    |    Лимиты.БанковскийСчет,
    |    Лимиты.Лимит,
    |    Лимиты.НеуменьшаемыйОстаток,
    |    0
    |ИЗ Лимиты КАК Лимиты";
 
 
    Запрос.Текст = Запрос.Текст+"
    |
    |ОБЪЕДИНИТЬ ВСЕ
    |
    |ВЫБРАТЬ
    |    ВЫБОР
    |        КОГДА ХозрасчетныйОстатки.Валюта ЕСТЬ NULL 
    |            ТОГДА &Рубли
    |        ИНАЧЕ ХозрасчетныйОстатки.Валюта
    |    КОНЕЦ,
    |    Кредиты.БанковскийСчет.Банк,
    |    0,
    |    0,
    |    0,
    |    0,
    |    Кредиты.БанковскийСчет,
    |    0,
    |    0,
    |    ХозрасчетныйОстатки.СуммаОстатокКт
    |ИЗ Кредиты 
    |    ЛЕВОЕ СОЕДИНЕНИЕ
    |    РегистрБухгалтерии.Хозрасчетный.Остатки(
    |        &КонецПериода,
    |        Счет В ИЕРАРХИИ (&СчетаУчетаКредитов),
    |        ,
    |        Организация = &Организация
    |            И Субконто1 В (&КонтрагентыБанки)
    |            И Субконто2 В (&ДоговорыСКонтрагентамиБанками)) КАК ХозрасчетныйОстатки
    |        ПО Кредиты.КонтрагентБанк = ХозрасчетныйОстатки.Субконто1 и Кредиты.ДоговорСКонтрагентомБанком = ХозрасчетныйОстатки.Субконто2";
 
    Запрос.УстановитьПараметр("Рубли", мВалютаРегламентированногоУчета);
    Запрос.УстановитьПараметр("СчетаУчетаКредитов", ПланыСчетов.Хозрасчетный.РасчетыПоКраткосрочнымКредитамИЗаймам);
    Запрос.УстановитьПараметр("КонтрагентыБанки", ДанныеОКредитах.ВыгрузитьКолонку("КонтрагентБанк"));
    Запрос.УстановитьПараметр("ДоговорыСКонтрагентамиБанками", ДанныеОКредитах.ВыгрузитьКолонку("ДоговорСКонтрагентомБанком"));
 
 
    Запрос.Текст = Запрос.Текст+"
    |
    |УПОРЯДОЧИТЬ ПО
    |    Валюта
    |ИТОГИ
    |    СУММА(СуммаНачальныйОстаток),
    |    СУММА(СуммаПриход),
    |    СУММА(СуммаРасход),
    |    СУММА(Лимит),
    |    СУММА(НеуменьшаемыйОстаток),
    |    СУММА(КредитПолученный)
    |ПО
    |    ОБЩИЕ,
    |    Валюта,
    |    БанковскийСчетБанк,
    |    БанковскийСчет";
 
    Запрос.УстановитьПараметр("КонецПериода", КонецДня(КонецПериода));
    Запрос.УстановитьПараметр("НачалоПериода", НачалоДня(НачалоПериода));
    Запрос.УстановитьПараметр("Организация", Организация);
 
    Результат = Запрос.Выполнить();